ufo_gnssroonedvarcheck_humidcheck_mod.f90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
! (C) Crown copyright Met Office. All rights reserved.
!     Refer to COPYRIGHT.txt of this distribution for details.
!-------------------------------------------------------------------------------
! Check values of humidity -limit to supersat and set <0.0 to = 0.0
!-------------------------------------------------------------------------------
 
module ufo_gnssroonedvarcheck_humidcheck_mod
 
use kinds
 
private
public :: ops_gpsro_humidcheck
 
contains
 
SUBROUTINE ops_gpsro_humidcheck (nstate, &
                                 nlevp,  &
                                 nlevq,  &
                                 za,     &
                                 zb,     &
                                 capsupersat, &
                                 x)
 
use ufo_constants_mod, only: &
    rd,                      &    ! Gas constant for dry air
    grav,                    &    ! Gravitational field strength
    c_virtual                     ! Related to mw_ratio
 
USE ufo_utils_mod, ONLY: &
    ops_qsat,            &
    ops_qsatwat
 
IMPLICIT NONE
 
! Subroutine arguments:
INTEGER, INTENT(IN)            :: nstate
INTEGER, INTENT(IN)            :: nlevp
INTEGER, INTENT(IN)            :: nlevq
REAL(kind_real), INTENT(IN)    :: za(:)
REAL(kind_real), INTENT(IN)    :: zb(:)
LOGICAL, INTENT(IN)            :: capsupersat   ! Whether to remove super-saturation (wrt ice?)
REAL(kind_real), INTENT(INOUT) :: x(:)
 
! Local declarations:
CHARACTER(len=*), PARAMETER :: routinename = "Ops_GPSRO_humidcheck"
INTEGER                     :: i
REAL(kind_real)                        :: p(nlevp)
REAL(kind_real)                        :: q(nlevq)
REAL(kind_real)                        :: t(nlevq)
REAL(kind_real)                        :: pb(nlevq)
REAL(kind_real)                        :: qsaturated(nlevq)
REAL(kind_real)                        :: tv
REAL(kind_real)                        :: pwt1
REAL(kind_real)                        :: pwt2
 
!---------------------------------------------------------------------
! 1. Check values of humidity -limit to supersat and set <0.0 to = 0.0
!---------------------------------------------------------------------
 
! Set up the P and Q vectors from x
 
p(:) = 1.0e2 * x(1:nlevp)           ! in Pa
q(:) = 1.0e-3 * x(nlevp + 1:nstate)    ! in kg/kg
 
DO i = 1, nlevq
 
  ! Calculate `mean P' for layer
 
  pwt1 = (za(i + 1) - zb(i)) / (za(i + 1) - za(i))
 
  pwt2 = 1.0 - pwt1
 
  pb(i) = exp(pwt1 * log(p(i)) + pwt2 * log(p(i + 1)))
 
  ! Derive the layer mean virtual temp. using the hydrostatic relationship
 
  tv = grav * (za(i + 1) - za(i)) / (rd * log(p(i) / p(i + 1)))
 
  ! Calculate the temperature
 
  t(i) = tv / (1.0 + c_virtual * q(i))
 
END DO
 
! Calculate the super.sat for T and Pmean
 
! For T < 0 Ops_Qsat returns the saturated specific humidity over ice.
! Supersaturation with respect to ice is possible, although is largely
! suppressed when CapSupersat is true. When CapSupersat is false the
! humidity check should be done with respect to water.
 
IF (capsupersat) THEN
  CALL ops_qsat (qsaturated, &  ! out
                 t,          &
                 pb,         &
                 nlevq)
ELSE
  CALL ops_qsatwat (qsaturated, &  ! out
                    t,          &
                    pb,         &
                    nlevq)
END IF
 
! Check no values have gone -ve
WHERE (x(nlevp + 1:nstate) < 0.0)
  x(nlevp + 1:nstate) = 1.0e-4
END WHERE
 
! Limit saturated value
WHERE (x(nlevp + 1:nstate) > 1.0e3 * qsaturated(1:nlevq))
  x(nlevp + 1:nstate) = 1.0e3 * qsaturated(1:nlevq)  ! in g/kg
END WHERE
 
END SUBROUTINE ops_gpsro_humidcheck
 
end module ufo_gnssroonedvarcheck_humidcheck_mod